Mikrotik: QoS pcq + queue tree

Share on facebook
Share on twitter
Share on telegram
Share on whatsapp
Share on email
Share on print

Para mejorar la navegación entre todos mis dispositivos me dcidí a configurar un simple Quality of Service (QoS) en mi router MikroTik.

El QoS (calidad de servicio) hace una distribución pareja del ancho de banda entre todos mis dispositivos. Así si estoy descargando un archivo en una pc, y viendo YouTube en otra, el internet se distribuirá de forma pareja entre ambas.

Pasemos a la configuración. Vamos a hacerlo sobre RouterOS v6.46.4.

Primero creamos las reglas subida y bajada en nuestro queue type.

/queue type
add kind=pcq name=BAJADA pcq-classifier=dst-address pcq-dst-address6-mask=64 pcq-src-address6-mask=64
add kind=pcq name=SUBIDA pcq-classifier=src-address pcq-dst-address6-mask=64 pcq-src-address6-mask=64

Ahora marcamos las distintas conexiones en el mangle, para despúes poder asignarles prioridad y ancho de banda.

/ip firewall mangle
add action=mark-connection chain=prerouting comment=ICMP new-connection-mark=icmp_conn passthrough=yes protocol=icmp
add action=mark-packet chain=prerouting connection-mark=icmp_conn new-packet-mark=icmp passthrough=no
add action=mark-connection chain=prerouting comment=DNS new-connection-mark=dns_conn passthrough=yes port=53 protocol=udp
add action=mark-packet chain=prerouting connection-mark=dns_conn new-packet-mark=dns passthrough=no
add action=mark-connection chain=prerouting comment="QUIC PROTOCOL (youtube)" new-connection-mark=quic_conn passthrough=yes port=443 protocol=udp
add action=mark-packet chain=prerouting connection-mark=quic_conn new-packet-mark=quic passthrough=no
add action=mark-connection chain=prerouting comment=WEB new-connection-mark=web_conn passthrough=yes port=80,443 protocol=tcp
add action=mark-packet chain=prerouting connection-mark=web_conn new-packet-mark=web passthrough=no
add action=mark-connection chain=prerouting comment=RESTO new-connection-mark=resto_conn passthrough=yes
add action=mark-packet chain=prerouting connection-mark=resto_conn new-packet-mark=resto passthrough=no

Después, agregamos las reglas en el queue tree para balancear los distintos tipos de conexiones.

/queue tree
add max-limit=10M name="QoS BAJADA" parent=bridge queue=BAJADA
add max-limit=2M name="QoS SUBIDA" parent=ether1 queue=SUBIDA
add limit-at=64k max-limit=512k name="ping bajada" packet-mark=icmp parent="QoS BAJADA" priority=1 queue=BAJADA
add limit-at=64k max-limit=512k name="dns bajada" packet-mark=dns parent="QoS BAJADA" priority=3 queue=BAJADA
add limit-at=1M max-limit=10M name="quic bajada" packet-mark=quic parent="QoS BAJADA" priority=7 queue=BAJADA
add limit-at=1M max-limit=10M name="web bajada" packet-mark=web parent="QoS BAJADA" priority=6 queue=BAJADA
add limit-at=1M max-limit=10M name="resto bajada" packet-mark=resto parent="QoS BAJADA" queue=BAJADA
add limit-at=64k max-limit=512k name="dns subida" packet-mark=dns parent="QoS SUBIDA" priority=3 queue=SUBIDA
add limit-at=64k max-limit=512k name="ping subida" packet-mark=icmp parent="QoS SUBIDA" priority=1 queue=SUBIDA
add limit-at=1M max-limit=2M name="resto subida" packet-mark=resto parent="QoS SUBIDA" queue=SUBIDA
add limit-at=1M max-limit=2M name="web subida" packet-mark=web parent="QoS SUBIDA" priority=6 queue=SUBIDA
add limit-at=1M max-limit=2M name="quic subida" packet-mark=quic parent="QoS SUBIDA" priority=7 queue=SUBIDA

Con estos simples 3 pasos tenemos un simple qos para implementar en nuestro hogar o equeña oficina.

5 respuestas

    1. es una configuración para 10mb, en caso de que necesites cambiarlo podes editar las lineas /queque tree
      add max-limit=10M name=”QoS BAJADA” parent=bridge queue=BAJADA
      add max-limit=2M name=”QoS SUBIDA” parent=ether1 queue=SUBIDA
      y en MAX LIMIT pones la velocidad de tu plan

Comenta!

A %d blogueros les gusta esto: